#-----------------------------------------------------------------------------
# Compiles the HL JPSS C library
#-----------------------------------------------------------------------------

cmake_minimum_required (VERSION 3.1.0)
project (HLJPSS_SRC)

#-----------------------------------------------------------------------------
# Define Sources
#-----------------------------------------------------------------------------
set (hljpss_obj
    hl_region_H5HLerror.c
    hl_region_H5HLint.c
    hl_region_H5LR.c
    hl_region_H5LT.c
)
set (HLJPSS_PUBLIC_HEADERS
    hl_region_H5LRpublic.h
    hl_region_H5LTpublic.h
    h5hl_region.h
    h5hl_api.h
)

add_library (${HLJPSS_C_LIB_TARGET} ${LIB_TYPE} ${hljpss_obj})
TARGET_C_PROPERTIES (${HLJPSS_C_LIB_TARGET} ${LIB_TYPE} " " " ")
target_link_libraries (${HLJPSS_C_LIB_TARGET} ${LINK_LIBS})
set_global_variable (HLJPSS_LIBRARIES_TO_EXPORT ${HLJPSS_C_LIB_TARGET})
HDF_SET_LIB_OPTIONS (${HLJPSS_C_LIB_TARGET} ${HLJPSS_C_LIB_NAME} ${LIB_TYPE})
set_target_properties (${HLJPSS_C_LIB_TARGET} PROPERTIES
    FOLDER libraries
    INTERFACE_INCLUDE_DIRECTORIES "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/include>"
)
if (USE_SHARED_LIBS)
  set_target_properties (${HLJPSS_C_LIB_TARGET} PROPERTIES
      COMPILE_DEFINITIONS "H5_BUILT_AS_DYNAMIC_LIB"
      INTERFACE_COMPILE_DEFINITIONS H5_BUILT_AS_DYNAMIC_LIB=1
  )
endif (USE_SHARED_LIBS)

#-----------------------------------------------------------------------------
# Add file(s) to CMake Install
#-----------------------------------------------------------------------------
  install (
      FILES
          ${HLJPSS_PUBLIC_HEADERS}
      DESTINATION
          ${HLJPSS_INSTALL_INCLUDE_DIR}
      COMPONENT
          headers
  )

#-----------------------------------------------------------------------------
# Add Target(s) to CMake Install for import into other projects
#-----------------------------------------------------------------------------
if (HLJPSS_EXPORTED_TARGETS)
  if (BUILD_SHARED_LIBS)
    INSTALL_TARGET_PDB (${HLJPSS_C_LIB_TARGET} ${HLJPSS_INSTALL_LIB_DIR} libraries)
  endif (BUILD_SHARED_LIBS)

  install (
      TARGETS
          ${HLJPSS_C_LIB_TARGET}
      EXPORT
          ${HLJPSS_EXPORTED_TARGETS}
      LIBRARY DESTINATION ${HLJPSS_INSTALL_LIB_DIR} COMPONENT libraries
      ARCHIVE DESTINATION ${HLJPSS_INSTALL_LIB_DIR} COMPONENT libraries
      RUNTIME DESTINATION ${HLJPSS_INSTALL_BIN_DIR} COMPONENT libraries
  )
endif (HLJPSS_EXPORTED_TARGETS)